複素数と有理数

Julia には複素数と有理数を表す型の定義が含まれ、これらの型に対する標準的な数学演算と初等関数もサポートされます。プリミティブ数値型であれ複合型であれ、組み込みの数値型には型の変換と昇格が定義され、どのように型を混ぜた演算であっても期待通りに動作します。

複素数

グローバル定数 im は複素数 i (-1 の平方根の主値) に束縛されます (数学者が使う i や工学者が使う j をこのグローバル定数に使う案は、添え字を表す変数と区別できなくなるということで採用されませんでした)。Julia では数値リテラルと識別子に続けて書くと数値リテラルが係数とみなされるので、この束縛さえあれば複素数に対する簡単な記法が手に入ります。数学で使われる伝統的な記法に似た記法です:

julia> 1+2im
1 + 2im

複素数に対しては標準的な算術演算が全て可能です:

julia> (1 + 2im)*(2 - 3im)
8 + 1im

julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im

julia> (1 + 2im) + (1 - 2im)
2 + 0im

julia> (-3 + 2im) - (5 - 1im)
-8 + 3im

julia> (-1 + 2im)^2
-3 - 4im

julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im

julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im

julia> 3(2 - 5im)
6 - 15im

julia> 3(2 - 5im)^2
-63 - 60im

julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im

型の昇格システムにより、オペランドの型を混ぜたとしても正しい演算が自動的に行われます:

julia> 2(1 - 1im)
2 - 2im

julia> (2 + 3im) - 1
1 + 3im

julia> (1 + 2im) + 0.5
1.5 + 2.0im

julia> (2 + 3im) - 0.5im
2.0 + 2.5im

julia> 0.75(1 + 2im)
0.75 + 1.5im

julia> (2 + 3im) / 2
1.0 + 1.5im

julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im

julia> 2im^2
-2 + 0im

julia> 1 + 3/4im
1.0 - 0.75im

3/4im == 3/(4*im) == -(3/4*im) となるのは、数値リテラル係数が除算よりも強く結合するためです。

複素数を引数に取る標準的な関数も定義されます:

julia> z = 1 + 2im
1 + 2im

julia> real(z)  # z の実部
1

julia> imag(z)  # z の虚部
2

julia> conj(z)  # z の共役
1 - 2im

julia> abs(z)   # z の絶対値
2.23606797749979

julia> abs2(z)  # z の絶対値の二乗
5

julia> angle(z) # z の位相角 (ラジアン)
1.1071487177940904

通常通り、複素数の絶対値 (abs) は原点からの距離です。abs2 が計算するのは絶対値の二乗であり、平方根を取らずに済むので複素数では特に有用となります。angle が計算するのは位相角 (ラジアン) であり、この関数は他の言語で argument あるいは arg と呼ばれることもあります。他の初等関数も一つ残らず複素数に対して定義されます:

julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im

julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im

julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991518im

julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im

julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im

数学関数の多くは実数に対して実数を返し、複素数に対して複素数を返します。例えば -1 == -1 + 0im が成り立ちますが、-1-1 + 0im に対する sqrt の動作は異なります:

julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]

julia> sqrt(-1 + 0im)
0.0 + 1.0im

数値リテラル係数は変数から複素数を作るときには利用できません。乗算記号を省略せずに書く必要があります:

julia> a = 1; b = 2; a + b*im
1 + 2im

ただし、この書き方は推奨されません。こうする代わりに、効率の良い complex 関数を使って実部と虚部から複素数の値を直接作成してください:

julia> a = 1; b = 2; complex(a, b)
1 + 2im

こうして複素数を作ると、乗算と加算が省略できます。

InfNaN は複素数の実部と虚部へ別々に伝播されます。そのときの挙動は特殊な浮動小数点数の値の節で説明した通りです:

julia> 1 + Inf*im
1.0 + Inf*im

julia> 1 + NaN*im
1.0 + NaN*im

有理数

Julia には二つの整数の比を正確に表現する有理数型があります。有理数型の値は // 演算子を使って作成します:

julia> 2//3
2//3

分母と分子が公約数を持つ場合は、分母が非負の既約分数になるよう通分が行われます:

julia> 6//9
2//3

julia> -4//8
-1//2

julia> 5//-15
-1//3

julia> -4//-12
1//3

こうして正規化された整数の比はユニークなので、有理数の等価性は分母と分子を比較することで確認できます。有理数の分母と分子はそれぞれ numerator 関数と denominator 関数で取り出せます:

julia> numerator(2//3)
2

julia> denominator(2//3)
3

有理数型に対しては通常の算術演算子と比較演算子が定義されているので、分母と分子と直接比較する必要は通常ありません:

julia> 2//3 == 6//9
true

julia> 2//3 == 9//27
false

julia> 3//7 < 1//2
true

julia> 3//4 > 2//3
true

julia> 2//4 + 1//6
2//3

julia> 5//12 - 1//4
1//6

julia> 5//8 * 3//12
5//32

julia> 6//5 / 10//7
21//25

有理数は浮動小数点数へ簡単に変換できます:

julia> float(3//4)
0.75

有理数から浮動小数点数への変換では、整数 a, b に対して次の等式が成り立ちます。唯一の例外は a == 0 かつ b == 0 の場合です:

julia> a = 1; b = 2;

julia> isequal(float(a//b), a/b)
true

無限大を表す有理数も構築できます:

julia> 5//0
1//0

julia> -3//0
-1//0

julia> typeof(ans)
Rational{Int64}

しかし、NaN を表す有理数の構築は認められていません:

julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]

これまでに何度も出てきているように、型の昇格システムのおかげで他の数値型とのやり取りは簡単です:

julia> 3//5 + 1
8//5

julia> 3//5 - 0.5
0.09999999999999998

julia> 2//7 * (1 + 2im)
2//7 + 4//7*im

julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im

julia> 3//2 / (1 + 2im)
3//10 - 3//5*im

julia> 1//2 + 2im
1//2 + 2//1*im

julia> 1 + 2//3im
1//1 - 2//3*im

julia> 0.5 == 1//2
true

julia> 0.33 == 1//3
false

julia> 0.33 < 1//3
true

julia> 1//3 - 0.33
0.0033333333333332993
日本語 Julia 書籍 (Amazon アソシエイト)
1 から始める Julia プログラミング
Julia プログラミングクックブック―言語仕様からデータ分析、機械学習、数値計算まで
スタンフォード ベクトル・行列からはじめる最適化数学